1. Reklam


    1. joysro
      ledas
      jungler
      keasro
      zeus
      karantina

ASP Konu Anlatımı ve Örnek Uygulamalar


  1. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanından Bilgileri Sayfaya Dökmek
    Seviye : Basit
    Kaynak Dosyalar : http://rapidshare.com/files/80706031/kayit_oku.rar

    bu dosyaları
    C:\Inetpub\wwwroot dizini içinde ders adında bir klasör oluşturun ve içerisine koyun. Bundan sonra yazdığım kodlarıda buraya koyarsınız.

    [​IMG]

    [​IMG]

    kayit_oku.asp
    Kod:
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    <html>
    <head>
    <title>Veritabanından kayıt okumak</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table border="1" cellpadding="0" cellspacing="0" width="100%">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
     
    dim objRs 
    set objRs = Server.CreateObject("ADODB.Recordset")
     objRs.CursorType = 0
     objRs.CursorLocation = 2
     objRs.LockType = 1
     
    dim strSql 
     strSql = "SELECT * FROM tblUye"
     objRs.Open strSql, objConn, , , &H0001
     
    if objRs.EOF then  
    %>
     <tr>
      <td>Veritabanı boş</td>
     </tr>	
    <%
    else   
    do while Not objRs.EOF
    %>
     <tr>
      <td><% = objRs("UYE_ID") %></td>
      <td><% = objRs("UYE_AD") %></td>
      <td><% = objRs("UYE_SOYAD") %></td>
      <td><% = objRs("UYE_MAIL") %></td>	
      <td><% = objRs("UYE_SEHIR") %></td>		
      <td><% = objRs("UYE_MESAJ") %></td>			 	
     </tr>	
    <%
     objRs.MoveNext()
    loop
    end if 
    
     objRs.Close
    set objRs = Nothing
    
     objConn.Close
    set objConn = Nothing
    %> 
    </table>	
    	
    </body>
    </html>
    

    kısaca açıklayacak olursak;
    strConn isimli bir değişken tanımladık ve bu değişkene veritabanı bağlantı cümlesini atadık. Başına str eki koyduk ki bu değişkenin bir string olduğunu bize her zaman hatırlatsın...
    Kod:
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    

    objConn isimli bir değişken tanımladık ve bu değişkene veritabanı bağlantımızı sağlayacak olan Connection nesnesini atadık. Başına obj eki koyduk ki bu değişkenin bir Server Object (Sunucu Nesnesi) olduğunu bize her zaman hatırlatsın...
    Veritabanına bağlantı sağladık...
    Kod:
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
    


    objRs isimli bir değişken tanımladık ve bu değişkene Recordset kayıtseti (kayıt dizisi) nesnesini atadık. Başına obj eki koyduk ki bu değişkenin bir Server Object (Sunucu Nesnesi) olduğunu bize her zaman hatırlatsın...
    Kod:
    dim objRs
    set objRs = Server.CreateObject("ADODB.Recordset")
    kayıtsetinin CursorType değerini 0 parametresi verdik.
    kayıtsetinin CursorLocation değerini 2 parametresi verdik.
    kayıtsetinin LockType değerini 1 parametresi verdik.
    Kod:
     objRs.CursorType = 0
     objRs.CursorLocation = 2
     objRs.LockType = 1
    
    Kayıtseti için verilebilecek bu değerler adovbs.inc dosyasında tanımlanmıştır.
    Kayıtsetinde onlarca farklı opsiyon ve bu opsiyonların birer nümerik karşılığı vardır. Normalde bu nümerik değerler yazılıdır.
    Nümerik ifadeleri akılda tutmak zor olduğu için bu nümerik ifadelerin karşılığını veren adovbs.inc kullanılır
    "1" yazmak yerine hatırlanması daha kolay olan "adOpenKeyset" yazabiliriz.

    Kayıtsetini açarken kullanabileceğimiz değerler aşağıdadır.

    <%
    '---- CursorTypeEnum Values ----
    Const adOpenForwardOnly = 0 <=== Biz bunu kullandık
    Const adOpenKeyset = 1
    Const adOpenDynamic = 2
    Const adOpenStatic = 3


    '---- CursorLocationEnum Values ----
    Const adUseServer = 2 <=== Biz bunu kullandık
    Const adUseClient = 3


    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1 <=== Biz bunu kullandık
    Const adLockPessimistic = 2
    Const adLockOptimistic = 3
    Const adLockBatchOptimistic = 4


    '---- EditModeEnum Values ----
    Const adEditNone = &H0000
    Const adEditInProgress = &H0001 <=== Biz bunu kullandık
    Const adEditAdd = &H0002
    Const adEditDelete = &H0004
    %>



    '---- CursorTypeEnum Values ----
    Recordset içindeki hareketi kontrol eden bir özelliktir. Varsayılan olarak Forward-only kullanılır. Dört değişik tipten biri seçilebilir.


    • Forward-only (adOpenForwardOnly ya da 0)
    • Keyset (adOpenKeyset ya da 1)
    • Dynamic (adOpenDynamic ya da 2)
    • Static (adOpenStatic ya da 3)

    Forward-only Cursor (adOpenForwardOnly ya da 0)
    Forward only : (Sadece ilerle)
    Varsayılan kürsördür.
    Static Cursor'e benzer fakat kayıtlar arasında sadece ileriye doğru harekete izin verir.
    Yeni kayıt ekleyemeyiz ve yapılan değişiklikler kayıtsetini yeniden açıncaya kadar göremeyiz. Bu kürsörü listeleme işlemlerinde kullanarak performans artışı sağlayabiliriz.

    Keyset Cursor (adOpenKeyset ya da 1)
    Kayıtseti içindeki her tütlü harekete izin verir.
    Diğer kullanıcıların eklediği kayıtların görünmesini engeller.
    Diğer kullanıcıların sildiği kayıtlara erişilmez.
    Diğer kullanıcıların kayıtlar üzerinde yaptığı veri değişiklikleri anında yansıtılır.

    Dynamic Cursor (adOpenDynamic ya da 2)
    Dynamic : (Dinamik) Diğer kullanıcılar tarafından yapılan eklemelerin, değişikliklerin ve silmelerin anında görülmesini sağlar ve kayıtseti üzerindeyapılacak tüm hareketlere izin verir.

    Static Cursor (adOpenStatic ya da 3)
    Static : (Duragan) Belli verilerin bulunması ya da raporların üretilmesi için kullanılacak kayıtsetinin değişmeyen bir kopyasını oluşturur. Veri üzerinde her türlü harekete izin verir. Diğer kullanıcılar tarafından yapılan değişiklikler kayıtsetine yansıtılmaz.

    '---- LockTypeEnum Values ----
    Kayıtsetinin kilitlenmesi için kullanılır. Dört farklı değer alabilir.

    adLockReadOnly ya da 1
    Veriler sadece okunur şekildedir, değiştirilemez.

    adLockPessimistic ya da 2
    Üzerinde işlem yapılan veriler satır bazında kilitlenir. Başka kullanıcıların erişimi engellenir.

    adLockOptimistic ya da 3
    Kayıtseti üzerinde işlem yapıp bunu tekrar veritabanına gönderene kadar kayıtseti üzerinde herhangi bir kilit yoktur.
    Veritabanının yenilenme (Update) süreci içinde kayıtseti kilitlenir.

    adLockBatchOptimistic ya da 4
    Değişiklikler toplu yapılır.



    kayıtseti dediğimiz nedir? Resme bakarsanız daha iyi anlayacaksınız. Okunan kayıtların üstünde gezinen o ok'a recordset denir...
    [​IMG]


    strSql isimli bir değişken tanımladık ve bu değişkene veritabanı içindeki tablomuza bağlantıyı sağlayacak ifadeyi atadık.
    Kod:
    dim strSql
     strSql = "SELECT * FROM tblUye"
    
    ve kayıtsetine yüklemiş olduğumuz tüm bu parametrelere uygun bir şekilde açılış yaptık.
    Kod:
     objRs.Open strSql, objConn, , , &H0001
    if = Eğer
    objRs = Kayıtseti (Nesnesi)
    EOF (End Of File) = Dosyanın, kuyruğun sonu..
    Kayıtsetinin sonunu gösterir.

    Türkçesi kayıtseti boş ise... demek. Accesste en son kayıt herzaman boştur. Hiç bir veri okunmadıysa kayıtseti bu satırdadır ve değeri false'dir. Tam türkçe ile veritabanı içindeki tblUye Boş ise demektir.
    Kod:
    if objRs.EOF then
    Boş olduğunu sayfaya yazıyoruz.
    Kod:
     <tr>
      <td>Veritabanı boş</td>
     </tr>
    

    üst tarafta if objRs.EOF then ile veritabanı boş ise demiştik else ile burada boş değilse demek istedik yani tabloya herhangi bir veri yazılmış ise bu koddan sonrası icra edilir...
    Kod:
    else
    do = yap, icra et, uygula
    while = ...ıncaya kadar...
    Not = ... Değilse(olumsuzluk) ...
    objRs = Kayıtseti (Nesnesi)
    EOF (End Of File) = Dosyanın, kuyruğun sonu..

    Tam türkçesi en son veriye kadar bu ilemi tekrar tekrar yap demektir.
    Kod:
    do while Not objRs.EOF

    tblUye isimli tablo içindeki alanlara verdiğimiz isimleri buradan çağırıyor ve içindekileri sayfaya aktarıyoruz. <% = %> bu Response.Write demektir.
    Kod:
     <tr>
      <td><% = objRs("UYE_ID") %></td>
      <td><% = objRs("UYE_AD") %></td>
      <td><% = objRs("UYE_SOYAD") %></td>
      <td><% = objRs("UYE_MAIL") %></td>	
      <td><% = objRs("UYE_SEHIR") %></td>		
      <td><% = objRs("UYE_MESAJ") %></td>			 	
     </tr>
    

    veiratanındaki ilk kayıt okunur. Kod buraya gelince aşağıdaki komut ile, hemen üstteki kısma do while Not objRs.EOF döner ve bu işi son verinin okunmasına ve kayıtsetinin boş satıra gelmesine kadar döner durur ve <tr> ile </tr> arasını her dönüşte bir alttaki satır içinde bulunan değerler ile doldurarak dönmeye devam eder.
    Kod:
     objRs.MoveNext()
    loop
    tblUye isimli tablonun boş olup olmadığını kontrol ettiğimiz kodu kapatıyoruz.
    Kod:
    end if 

    Kayıtseti nesnesini kapatıyor ve değerlerini boşaltıyoruz. Bunu yapmazsak kodumuz onlarca kullanıcı ile çalıştığında hem sayfanın geç açılmasına hemde sunucuyu boşa meşgul ederek sunucuyu yormaya ve performansını düşürmemize sebep oluruz.
    Kod:
     objRs.Close
    set objRs = Nothing
    

    Bağlantı nesnesini de kapatıyor ve değerlerini boşaltıyoruz.
    Kod:
     objConn.Close
    set objConn = Nothing
    
     
  2. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanına (Access) Yeni Kayıt Girmek.
    Seviye : Basit
    Kaynak Dosyalar :
    http://rapidshare.com/files/4161156/ders02.rar.html


    wwwroot içine DERS isimli Klasöre koyun ve unutmayın DERS klasörüne yazma izni verin.
    Yazma izni nasıl veririm?
    DERS klasörüne sağ tıklayın ve özelliklerden Web Paylaşımı sekmesine geçin. Bu klasörü Paylaşın radio düğmesini işaretleyiniz bir sihirbaz açılacak oradaki yazma vb. seçenekleri seçip uygulayın...



    İlk önce bir form sayfasına ihtiyacımız var.

    kayit_form.html

    Kod:
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    
    <html>
    <head>
    <title>Kayıt Formu</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table align="center" border="0" cellpadding="0" cellspacing="0" width="300">
    
    <form action="kayit_kaydet.asp" method="post">
    
     <tr>
      <td>Ad :</td> 
      <td><input type="text" name="txtAd" size="20" maxlength="15" value=""></td>	
     </tr>
     	
     <tr>
      <td>Soyad :</td> 
      <td><input type="text" name="txtSoyad" size="20" maxlength="25" value=""></td>	
     </tr>
     
     <tr>
      <td>Mail :</td> 
      <td><input type="text" name="txtMail" size="20" maxlength="30" value=""></td>	
     </tr> 
     
     <tr>
      <td>Şehir :</td> 
      <td>
       <select name="txtSehir">
        <option value="Adana">Adana</option>
        <option value="Adıyaman">Adıyaman</option>	
        <option value="Afyon">Afyon</option>		
        <option value="Ağrı">Ağrı</option>				
        <option value="Amasya">Amasya</option>	
        <option value="Ankara">Ankara</option>						
       </select>
      </td>	
     </tr>  
     
     <tr>
      <td>Mesaj :</td> 
      <td><textarea rows="5" cols="30" name="txtMesaj"></textarea></td>	
     </tr>  
     
     <tr>
      <td>&nbsp;</td> 
      <td><input type="submit" value="Kaydet"></td>	
     </tr> 
     
    </form>
     
    </table>
    
    </body>
    </html>
    

    formdan gelen bilgileri veritabanına kaydedecek asp sayfamız.

    kayit_kaydet.asp

    Kod:
    <%
    'Adovbs.inc dosyası içindeki sabitlerimiz. Kayıt işlemi yaparken lazım olacak....
    const adCmdText = &H0001
    const adExecuteNoRecords = &H00000080
    
    
    'Form içindeki name="txtAd" isimli form elemanımızdan içine yazılmış olan ismi alıyor ve bu değeri strAd değişkenine atıyoruz(yüklüyoruz).
    dim strAd
     strAd = Request.Form("txtAd")
    
    'Form içindeki name="txtSoyad" isimli form elemanımızdan içine yazılmış olan soyismi alıyor ve bu değeri strSoyad değişkenine atıyoruz(yüklüyoruz).
    dim strSoyad
     strSoyad = Request.Form("txtSoyad")
     
    'Form içindeki name="txtMail" isimli form elemanımızdan içine yazılmış olan Mail adresini alıyor ve bu değeri strMail değişkenine atıyoruz(yüklüyoruz).
    dim strMail
     strMail = Request.Form("txtMail") 
     
    'Form içindeki name="txtSehir" isimli form elemanımızdan içine yazılmış olan Sehir ismini alıyor ve bu değeri strSehir değişkenine atıyoruz(yüklüyoruz).
    dim strSehir
     strSehir = Request.Form("txtSehir")  
     
    'Form içindeki name="txtMesaj" isimli form elemanımızdan içine yazılmış olan Mesajı alıyor ve bu değeri strMesaj değişkenine atıyoruz(yüklüyoruz).
    dim strMesaj
     strMesaj = Request.Form("txtMesaj") 
     
    'Veritabanına Bağlanıyoruz.
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    'Bağlantıyı açıyoruz.
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
    
    strSql = "INSERT INTO tblUye(UYE_AD, UYE_SOYAD, UYE_MAIL, UYE_SEHIR, UYE_MESAJ) VALUES('" & strAd & "', '" & strSoyad & "', '" & strMail & "', '" & strSehir & "', '" & strMesaj & "')"
    
    
     objConn.Execute(strSql),,adCmdText + adExecuteNoRecords
     
     
    'Bağlantıyı kapatıyoruz. 
     objConn.Close
    set objConn = Nothing
    
    'Yazdığımız kaydı gösteren sayfaya "kayit_oku.asp" yönlendiriyoruz.. 
     Response.Redirect "kayit_oku.asp"
    %> 
    


    konuyu açıklayıcı resimler aşağıda...

    [​IMG]



    [​IMG]
     
  3. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanından Bilgileri Güncellemek
    Seviye : Basit
    Kaynak Dosyalar :
    http://rapidshare.com/files/16809713/merakli_asp_ile_guncelleme.rar


    Öncelikle şema olarak anlatıyorum altta kodları vereceğim. Kodları zaman zaman açıklayacağım.

    [​IMG]

    Güncellenecek bilgileri listeleyeğimiz sayfamız.
    kayit_oku.asp
    Kod:
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    <html>
    <head>
    <title>Veritabanından kayıt okumak</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table border="1" cellpadding="0" cellspacing="0" width="100%">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
     
    dim objRs 
    set objRs = Server.CreateObject("ADODB.Recordset")
     objRs.CursorType = 0
     objRs.CursorLocation = 2
     objRs.LockType = 1
     
    dim strSql 
     strSql = "SELECT * FROM tblUye"
     objRs.Open strSql, objConn, , , &H0001
     
    if objRs.EOF then  
    %>
     <tr>
      <td>Veritabanı boş</td>
     </tr>	
    <%
    else 
    
    dim intSayac
     intSayac = 0
    
    dim strRenk  
    do while Not objRs.EOF
    if intSayac mod 2 then
     strRenk = "#e8e8e8"
    else
     strRenk = "#ffffcc"
    end if
    %>
     <tr bgcolor="<% = strRenk %>">
      <td><% = objRs("UYE_AD") %></td>
      <td><% = objRs("UYE_SOYAD") %></td>
      <td><a href="guncelle.asp?id=<% = objRs("UYE_ID") %>">Güncelle</a></td>		 	
     </tr>	
    <%
     intSayac = intSayac + 1
     objRs.MoveNext
    loop
    end if 
    
     objRs.Close
    set objRs = Nothing
    
     objConn.Close
    set objConn = Nothing
    %> 
    </table>	
    	
    </body>
    </html>
    


    Güncellenecek veri bilgilerinin form elemanları içerisine alınıp değişiklik yapacağımız sayfa.
    guncelle.asp
    Kod:
    <% @ Language=VBScript CodePage="1254" %>
    <%
    Option explicit
     Response.Buffer = true
    %>
    <%
    dim intUyeID
    if Request.QueryString("id") <> "" then
     intUyeID = Request.QueryString("id")
    else
     Response.Redirect("kayit_oku.asp")
    end if
    
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
    %>
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    
    <html>
    <head>
    <title></title>
    <style type="text/css">
    <!-- 
    body {
     margin:0px;
     padding:0px;
    } 
    -->
    </style>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table border="0" cellpadding="0" cellspacing="0" width="100%">
     <tr>
      <td align="center">
    <%		
    dim objRs
    set objRs = Server.CreateObject("ADODB.Recordset")
     objRs.CursorLocation = 3
     objRs.CursorType = 0
     objRs.LockType = 3
     
    dim strSql
     strSql = "SELECT * FROM tblUye WHERE UYE_ID = " & intUyeID & ""
     objRs.Open strSql, objConn, , , &H0001
    
    if not objRs.EOF then
    dim strAd
     strAd = objRs("UYE_AD")
     
    dim strSoyad
     strSoyad = objRs("UYE_SOYAD") 
     
    dim strMail
     strMail = objRs("UYE_MAIL")  
     
    dim strSehir
     strSehir = objRs("UYE_SEHIR")  
     
    dim strMesaj
     strMesaj = objRs("UYE_MESAJ")
    %>
       <table border="0" cellpadding="0" cellspacing="0" width="779">
       <form action="guncelle_islem.asp" method="POST">
       <input type="hidden" name="id" value="<% = intUyeID %>">
        <tr>
         <td width="120">Ad :</td>
         <td><input type="text" name="ad" value="<% = strAd %>" size="20"></td>
        </tr>
        <tr>
         <td width="120">Soyad :</td>
         <td><input type="text" name="soyad" value="<% = strSoyad %>" size="20"></td>
        </tr>
        <tr>
         <td width="120">Mail :</td>
         <td><input type="text" name="mail" value="<% = strMail %>" size="20"></td>
        </tr>
        <tr>
         <td width="120">Şehir :</td>
         <td>
          <select name="sehir">
    <%
    dim arrIller
     arrIller = Array("Seçiniz","Adana","Adıyaman","Afyon","Ağrı",
    "Aksaray","Amasya","Ankara","Antalya","Ardahan","Artvin",
    "Aydın","Balıkesir","Bartın","Batman","Bayburt",
    "Bilecik","Bingöl","Bitlis",
    "Bolu","Burdur","Bursa","Çanakkale","Çankırı","Çorum","Denizli",
    "Diyarbakır","Düzce","Edirne","Elazığ","Erzincan","Erzurum",
    "Eskişehir","Gaziantep","Giresun","Gümüşhane","Hakkari",
    "Hatay","Iğdır","Isparta",
    "İstanbul","İzmir","K.Maraş","Karabük","Karaman","Kars",
    "Kastamonu","Kayseri","Kırıkkale","Kırklareli","Kırşehir",
    "Kilis","Kocaeli","Konya","Kütahya","Malatya",
    "Manisa","Mardin","Mersin",
    "Muğla","Muş","Nevsehir","Niğde","Ordu","Osmaniye",
    "Rize","Sakarya","Samsun","Siirt","Sinop","Sivas","Şanlıurfa","Şırnak",
    "Tekirdağ","Tokat","Trabzon","Tunceli","Uşak","Van",
    "Yalova","Yozgat","Zonguldak")
    dim strSelected
    dim intSayac
    for intSayac = 0 to UBound(arrIller)
    if arrIller(intSayac) <> "" then
    if arrIller(intSayac) = strSehir then strSelected=" selected" else strSelected=""
    end if
     Response.Write "       <option value=""" & arrIller(intSayac) & """" & strSelected & ">" & arrIller(intSayac) & "</option>" & vbNewLine
    next
    %>	
          </select>
         </td>
        </tr>
        <tr>
         <td width="120" valign="top">Mesaj :</td>
         <td><textarea rows="5" cols="35" name="mesaj" class="input"><% = strMesaj %></textarea></td>
        </tr>
        <tr>
         <td width="120">&nbsp;</td>
         <td><input type="submit" value="Güncelle"></td>
        </tr>
       </form>		
       </table>
    <%		
    end if		
    
     objRs.Close
    Set objRs = Nothing	 		
    %> 
      </td> 
     </tr>	
    </table>
    
    </body>
    </html>
    <%		
     objConn.Close
    Set objConn = Nothing
    %> 



    Değiştirilen bilgileri formdan alıp veritabanına kaydedecek olan sayfamız.
    guncelle_islem.asp
    Kod:
    <%
     intUyeID = Request.Form("id")
     strAd    = Request.Form("ad")
     strSoyad = Request.Form("soyad")
     strMail  = Request.Form("mail")
     strSehir = Request.Form("sehir")
     strMesaj = Request.Form("mesaj")
     
    const adCmdText = &H0001
    const adExecuteNoRecords = &H00000080
     
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    dim objConn  
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
     
     strSql = "UPDATE tblUye SET UYE_AD = '" & strAd  & "', UYE_SOYAD = '" & strSoyad  & "', UYE_MAIL = '" & strMail  & "', UYE_SEHIR = '" & strSehir  & "', UYE_MESAJ = '" & strMesaj  & "' WHERE UYE_ID = " & intUyeID
     objConn.Execute(strSql),,adCmdText + adExecuteNoRecords
    
     objConn.Close
    Set objConn = Nothing
    
     Response.Redirect "kayit_oku.asp"
    %> 
     
  4. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Sayfalama İşlemi
    Seviye : Orta
    Kaynak Dosyalar : http://rapidshare.com/files/6071967/sayfalama_ornegi.rar.html

    Kod:
    <% @ Language = VBScript CodePage = 1254 %>
    <%
    '/////////////////////////////////////////////////////////////////
    Option Explicit
     Response.Buffer = True
     Response.Expires = -1
    '/////////////////////////////////////////////////////////////////
    '---- CursorTypeEnum Values ----
    Const adOpenStatic = 3
    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1
    '---- CommandTypeEnum Values ----
    Const adCmdText = &H0001
    '/////////////////////////////////////////////////////////////////
    Dim intHerSayfadaGosterilecekKayit
     intHerSayfadaGosterilecekKayit = 20 
    'intHerSayfadaGosterilecekKayit (Her sayfada göstereceğiniz kayıt sayısı ile değiştirebilirsiniz.)
    
     
    Dim intSayfa
    if Request.QueryString("s") = "" then
     intSayfa = 1
    else
     intSayfa = CInt(Request.QueryString("s"))
    end if
    'intSayfa (Açık olan sayfa sayısını alırız. Sayfa "s" değişkeninin değeri yok ise 1 değeri atanır. Bu değer boş değil ise sayfadan gönderilen sayı alınır.)
    '/////////////////////////////////////////////////////////////////
    %>
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    
    <html>
    <head>
    <title>ornek</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    <style type="text/css">
    <!-- 
    body {
     margin:0px;
     padding:0px;
    } 
    .sayfa {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:bold; 
     color: #ffcc00; 
    }
    A.link_01:link {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:bold; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:visited {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:bold; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:active {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:bold; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:hover {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:bold; 
     color: #ffcc00; 
     text-decoration: none
    }
    -->
    </style>
    </head>
    <body>
    
    <table align="center" border="0" cellpadding="0" cellspacing="0" width="100%">
     <tr>
      <td>
       <table border="0" cellpadding="0" cellspacing="0" width="779">
        <tr>
         <td colspan="2" height="80">&nbsp;</td>
        </tr>
        <tr>
         <td width="179">&nbsp;</td>
         <td width="600">
          <table border="1" cellpadding="0" cellspacing="0" width="100%">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn
    
    dim objRs
    set objRs = Server.CreateObject("ADODB.Recordset")
     
    dim strSql
     strSql = "SELECT * FROM tblVeri"
     
     objRs.PageSize  = intHerSayfadaGosterilecekKayit '(Bir sayfada görüntülenecek kayıt sayısını belirtir.)
     objRs.CacheSize = intHerSayfadaGosterilecekKayit
    
     objRs.Open strSql, objConn, adOpenStatic, adLockReadOnly, adCmdText
     
    dim intToplamSayfa
     intToplamSayfa = objRs.PageCount
    
    if intSayfa > intToplamSayfa then intSayfa = intToplamSayfa
    if intSayfa < 1 then intSayfa = 1
    
    if objRs.EOF then
    'if intToplamSayfa = 0 then
    %>
           <tr>
            <td align="center" valign="middle" height="200" class="sayfa">Kayıt yok</td>
           </tr>
    <%
    else
     objRs.AbsolutePage = intSayfa '(kayıtsetine hangi sayfada olduğunu bildirir.)
    %>
           <tr>
            <td align="center" class="sayfa">Toplam <%= intToplamSayfa %> sayfa bulunmakta ve siz <%= intSayfa %>. sayfadasınız.</td>
           </tr>
    <%
    dim intSayac01
     intSayac01 = 0
    do while intSayac01 < intHerSayfadaGosterilecekKayit And Not objRs.EOF
    %>			 
           <tr>
            <td><% = objRs("veri") %></td>
           </tr>
    <%
     intSayac01 = intSayac01 + 1
     objRs.MoveNext
    loop
    %>			 
           <tr>
            <td align="center">
    <%
    if intSayfa > 1 then
    %>
             <B><a href="sayfalama.asp?s=<%= intSayfa - 1 %>" class="link_01">[&lt;&lt; Geri]</a>&nbsp;</B> 
    <%
    end if
    
    dim intSayac02			
    for intSayac02 = 1 To intToplamSayfa
    if intSayac02 = intSayfa then
    %>
             <font class="sayfa"><%= intSayac02 %></font> 
    <%
    else
    %>
             <B><a href="sayfalama.asp?s=<%= intSayac02 %>" class="link_01"><%= intSayac02 %></a></B> 
    <%
    end if
    next
    			
    if intSayfa < intToplamSayfa then
    %>
             <B>&nbsp;<a href="sayfalama.asp?s=<%= intSayfa + 1 %>" class="link_01">[ileri &gt;&gt;]</a></B> 
    <%
    end if
    %>					
            </td>
           </tr>
    <%
    end if
    
     objRs.Close
    set objRs = Nothing
    
     objConn.Close
    set objConn = Nothing
    %>
          </table>
    		 </td>		
        </tr>			
        <tr>
         <td colspan="2" height="20">&nbsp;</td>
        </tr>		
       </table>
      </td>
     </tr>
    </table>
    
    </body>
    </html>
    
    Gereken kısımlara not düştüm. Hala anlaşılmayan bir şey varsa sorulan kısımları açıklayayım.
     
  5. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanındaki Bilgileri İki Sutun halinde Sayfaya Dökmek
    Seviye : Orta
    Kaynak Dosyalar :
    http://rapidshare.com/files/6080862/portal_menu.rar.html


    [​IMG]


    Kod:
    <% @ Language=VBScript CodePage="1254" %>
    <%
    Option explicit
     Response.Buffer = true
    %>
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    <html>
    <head>
    <title>ornek</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    <style type="text/css">
    <!-- 
    body {
     margin:0px;
     padding:0px;
    } 
    .sayfa {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #ffcc00; 
    }
    A.link_01:link {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:visited {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:active {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:hover {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #ffcc00; 
     text-decoration: none
    }
    -->
    </style>
    </head>
    <body leftmargin="0" topmargin="0">
    <table border="0" cellpadding="0" cellspacing="0" width="100%">
     <tr>
      <td>
       <table align="center" border="0" cellpadding="0" cellspacing="0" width="769" bgcolor="#ffffff">
        <tr>
         <td align="center" height="120">üst banner alanı</td>
        </tr>
        <tr>
         <td>
          <table border="0" cellpadding="0" cellspacing="0" width="100%">
          <tr>
           <td width="1"><img src="resimler/bosluk.gif" alt="" width="1" height="1" border="0"></td>
           <td align="center" width="160" valign="top">Sol menu</td>
           <td width="1"><img src="resimler/bosluk.gif" alt="" width="4" height="1" border="0"></td>
           <td width="600" valign="top">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
     
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
    
    dim objRsKategori 
    set objRsKategori = Server.CreateObject("ADODB.Recordset")
     objRsKategori.CursorLocation = 2
     objRsKategori.CursorType = 1
     objRsKategori.LockType = 3
    
    dim strSqlKategori
     strSqlKategori = "SELECT * FROM tblKategori"
     objRsKategori.Open strSqlKategori, objConn, , , &H0001
    
     Response.Write "<table align=""center"" border=""1"" cellpadding=""3"" cellspacing=""0""  width=""100%"">" & vbNewLine 
    
    if objRsKategori.EOF and objRsKategori.BOF then
     Response.Write "         <tr>" & vbNewLine & _
     "          <td height=""400"" align=""center"" valign=""middle"">Kayıt Yok!</td>" & vbNewLine & _ 
     "         </tr>" & vbNewLine 
    
    else
    
    dim intToplamVeri
     intToplamVeri = objRsKategori.RecordCount
     
    dim intSutun
     intSutun = 2
     
    dim intSay
    do while not objRsKategori.EOF
    
     intSay = intSay + 1
    if intSay Mod intSutun = 1 then 
     Response.Write "         <tr>" & vbNewLine
    end if
     
     Response.Write "          <td valign=""top""><a href=""kategori.asp?id=" & objRsKategori("KATEGORI_ID") & """ class=""link_01""><b>" & objRsKategori("KATEGORI_AD") & "</b></a><br>"
    '/////////////////////////////////////////////////////////////////////////////////////////////////////////
    dim objRsAltKategori 
    set objRsAltKategori = Server.CreateObject("ADODB.Recordset")
     objRsAltKategori.CursorLocation = 2
     objRsAltKategori.CursorType = 1
     objRsAltKategori.LockType = 3
     
    dim strSqlAltKategori 
     strSqlAltKategori = "SELECT * FROM tblKategoriAlt WHERE KATEGORI_ID = " & objRsKategori("KATEGORI_ID")
     objRsAltKategori.Open strSqlAltKategori, objConn, , , &H0001
    if not objRsAltKategori.EOF then
    do while not objRsAltKategori.EOF
     Response.Write "<a href=""altkategori.asp?kategori=" & objRsKategori("KATEGORI_ID") & "&altkategori=" & objRsAltKategori("KATEGORI_ALT_ID") & """ class=""link_01"">" & objRsAltKategori("KATEGORI_ALT_AD") & "</a><br>"
     objRsAltKategori.MoveNext
    loop
    end if
     objRsAltKategori.Close
    set objRsAltKategori = Nothing	  
    '/////////////////////////////////////////////////////////////////////////////////////////////////////////
     Response.Write "</td>" & vbNewLine
    
    if intSay Mod intSutun = 0 then 
     Response.Write "         </tr>" & vbNewLine
    end if
    
     objRsKategori.MoveNext
    loop
    
    if intToplamVeri mod intSutun <> 0 then
    dim i
    for i = 1 to (intSutun - (intToplamVeri mod intSutun))
     Response.Write "          <td>&nbsp;</td>" & vbNewLine
    next
    end if
     Response.Write "         </tr>" & vbNewline
    end if 
     Response.Write "			  </table>" & vbNewline
    
     
     objRsKategori.Close
    set objRsKategori = Nothing	 		
    
     objConn.Close
    set objConn = Nothing
    %>				
    			 </td>		
           <td width="1"><img src="resimler/bosluk.gif" alt="" width="4" height="1" border="0"></td>
           </tr>
          </table>	 
    		 </td>
        </tr>		
        <tr>
         <td align="center" height="40">sayfa altı</td>
        </tr>			
       </table>
      </td>
     </tr>
    </table>
    </body>
    </html>
     
  6. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanından Alınan Kayıtların Her Satırını Bir Önceki Satırdan Farklı Bir Renkle Sayfaya Dökmek.
    Seviye : Basit
    Kaynak Dosyalar : http://rapidshare.com/files/6083185/renkli_sutunlar.rar.html

    Bu örneği veritabanından bilgileri sayfaya döktüğümüz örnek üzerinden göstereceğim.

    Yapacağımız Uygulamanın görüntüsü
    [​IMG]

    Bu işlemi yapan kodları kırmızı ile seçiyorum.

    Kod:
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    <html>
    <head>
    <title>Veritabanından kayıt okumak</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table border="1" cellpadding="0" cellspacing="0" width="100%">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    'strConn = "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("veritabani.mdb") 
    
    dim objConn
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
     
    dim objRs 
    set objRs = Server.CreateObject("ADODB.Recordset")
     objRs.CursorType = 0
     objRs.CursorLocation = 2
     objRs.LockType = 1
     
    dim strSql 
     strSql = "SELECT * FROM tblUye"
     objRs.Open strSql, objConn, , , &H0001
     
    if objRs.EOF then  
    %>
     <tr>
      <td>Veritabanı boş</td>
     </tr>	
    <%
    else 
    
    [B]dim intSayac
     intSayac = 0[/B]
    
    dim strRenk  
    do while Not objRs.EOF
    [B]if intSayac mod 2 then
     strRenk = "#e8e8e8"
    else
     strRenk = "#ffffcc"
    end if[/B]
    %>
     <tr bgcolor[B]="<% = strRenk %>[/B]">
      <td><% = objRs("UYE_ID") %></td>
      <td><% = objRs("UYE_AD") %></td>
      <td><% = objRs("UYE_SOYAD") %></td>
      <td><% = objRs("UYE_MAIL") %></td>	
      <td><% = objRs("UYE_SEHIR") %></td>		
      <td><% = objRs("UYE_MESAJ") %></td>			 	
     </tr>	
    <%
     [B]intSayac = intSayac + 1[/B]
     objRs.MoveNext
    loop
    end if 
    
     objRs.Close
    set objRs = Nothing
    
     objConn.Close
    set objConn = Nothing
    %> 
    </table>	
    	
    </body>
    </html>
    
     
  7. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Veritabanından Rastgele Veri Okumak.
    Seviye : Basit
    Kaynak Dosyalar : http://rapidshare.com/files/996201/randomize.rar.html


    Kod:
    <% @ Language=VBScript CodePage="1254" %>
    <%
    
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
     set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn
    
     Response.Write "<table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""250"">" & vbNewLine
     
    set objRs=server.createobject("adodb.recordset")
     strSql = "select * from tblSozler"
     objRs.open strSql, objConn, 1, 3
     
    [B]randomize    
     intRastgelenKayit = Int((objRs.RecordCount * Rnd)+ 0)
     objRs.Move(intRastgelenKayit) [/B]
     
     Response.Write "<tr>" & vbNewLine & _
     "<td height=""100"" valign=""top"">" & objRs("soz") & "</td>" & vbNewLine & _
     "</tr>" & vbNewLine & _
     "<tr>" & vbNewLine & _
     "<td align=""right"">" & objRs("yazar") & "</td>" & vbNewLine & _
     "</tr>" & vbNewLine
     objRs.close
    set objRs = Nothing
    
     Response.Write "</table>" & vbNewLine
    
     objConn.close
    set objConn = Nothing
    %> 
    
     
  8. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Recursion İşlemi
    Seviye : Üst Düzey
    Kaynak Dosyalar : http://rapidshare.com/files/6087434/recursion.rar.html

    Asp ile Kategoriler içeren Shop, Makale, Forum vb. script yazmak ve bunu profesyonel bir veritabanı mimarisi, sonsuz kategori ve en son sistem bir uygulama yapmak istiyorlar ise mutlaka bu işlemi kullanmalıdırlar. hipernex.com, hepsiburada.com ve bunlar gibi sitelerin kodlamaları asp.NET ile yapılmıştır ancak veritabanı mimarisi bu şekildedir...

    Bu konuda TR çok fazla bir kaynak bulamazsınız. Bu konuda araştırmak kafa yormanız için bu bir başlangıç olsun...

    Ekran çıktışı şöyle;
    Elbette bu çok farklı şekillerde kullanılır ben en basit halini yaptım.

    [​IMG]

    Kod:
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
    
    <html>
    <head>
    <title></title>
    <style type="text/css">
    <!-- 
    body {
     margin:0px;
     padding:0px;
    }
    A.link_01:link {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:visited {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:active {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #0077b5; 
     text-decoration: none
    }
    A.link_01:hover {
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 12px; 
     font-weight:normal; 
     color: #ffcc00; 
     text-decoration: none
    }
    -->
    </style>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
    </head>
    <body>
    
    <table border="0" cellpadding="0" cellspacing="0" width="100%">
     <tr>
      <td align="center">
       <table border="0" cellpadding="0" cellspacing="0" width="779">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn
    
     [B]subRecursive 0, 0[/B]
    
     objConn.Close 
    Set objConn= Nothing 
    %>
       </table>		
      </td> 
     </tr>	
    </table>
    
    </body>
    </html>
    <%
    sub subRecursive(ParentID, intLevel)
    dim objRs
    dim strSql
    
     strSql = "SELECT KATEGORI_ID, KATEGORI_AD FROM tblKategori WHERE KATEGORI_UST_ID = " & ParentID     
    set objRs = objConn.Execute(strSql) 
    
    if Not objRs.EOF then     
    do while Not objRs.EOF
     Response.Write "    <tr>" & vbNewLine & _
     "     <td><img src=""bosluk.gif"" border=""0"" width=""" & 25 * intLevel & """ height=""1""><a href=""01.asp?id=" & objRs("KATEGORI_ID") & """ class=""link_01"">" & objRs("KATEGORI_AD") & "</a></td>" & vbNewLine & _
     "    </tr>" & vbNewLine
     subRecursive objRs("KATEGORI_ID"), intLevel + 1 
     objRs.MoveNext
    loop
    end if 
     
    if Not objRs Is Nothing then
     objRs.Close
    end if
    set objRs = Nothing
        
    end sub
    %> 
    
     
  9. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Dinamik Haber Başlıkları (Asp+JavaScript)
    Seviye : Orta Düzey
    Kaynak Dosyalar : http://rapidshare.com/files/6152754/haber_basliklari.rar.html


    Görünüm
    [​IMG]


    Kod:
    <html>
    <head>
    <title>haber</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9" />
    <style type="text/css">
    <!-- 
    
    a.Link_01:link {
      font-family: Verdana, Arial, Helvetica, sans-serif; 
    	font-size: 12px; 
    	font-weight:bold; 
    	color: #FF9900; 
    	text-decoration: none
    }
    a.Link_01:visited {
      font-family: Verdana, Arial, Helvetica, sans-serif; 
    	font-size: 12px; 
    	font-weight:bold; 
    	color: #FF9900; 
    	text-decoration: none
    }
    a.Link_01:active {
      font-family: Verdana, Arial, Helvetica, sans-serif; 
      font-size: 12px; 
      font-weight:bold; 
      color: #FF9900; 
      text-decoration: none
    }
    a.Link_01:hover {
      font-family: Verdana, Arial, Helvetica, sans-serif; 
    	font-size: 12px; 
    	font-weight:bold; 
    	color: #CB2300; 
    	text-decoration: underline
    }
    .baslik
    {
     color: #FF9900; 
     font-family: Verdana, Arial, Helvetica, sans-serif; 
     font-size: 13px; 
     font-weight: bold
    }
    .yazi_01 {
     font-family: Verdana, sans-serif, Helvetica, Arial; 
     font-size: 10px; 
     line-height: 16px;
    }
    .yazi_02 {
     color: #CB2300; 
     font-family: Verdana, sans-serif, Helvetica, Arial; 
     font-size: 14px; 
    }
    -->
    </style>
    <script type="text/javascript">
    <!--
    function hide(divID)
    {
     document.getElementById(''+divID+'').style.display = 'none';
    }
    function displayCatDiv(divID)
    {
     document.getElementById(''+divID+'').style.display = 'block';
    }
    // -->
    </script>
    </head>
    <body>
    
    <table border="1" cellpadding="0" cellspacing="0" width="550">
    <%
    dim strConn 
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
     
    '---- CursorTypeEnum Values ----
    Const adOpenForwardOnly = 0
    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1
    '---- CommandTypeEnum Values ----
    Const adCmdText = &H0001
    '---- GetRowsOptionEnum Values ----
    Const adGetRowsRest = -1
    
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn
     
     strSql = "Select * From tblHaber"
    
    set objRs = Server.CreateObject("ADODB.Recordset")
     objRs.open strSql, objConn, adOpenForwardOnly, adLockReadOnly, adCmdText
    	
    if objRs.EOF then
     intToplam = ""
    else
     arrTumVeriler = objRs.GetRows(adGetRowsRest)
     intToplam = UBound(arrTumVeriler,2)
    end if
    
     objRs.Close
    set objRs = nothing
    
    if intToplam <> "" then
    
     intAlan01 = 0
     intAlan02 = 1 
     intAlan03 = 2  
     intAlan04 = 3  
     intAlan05 = 4   
     
    
     Response.Write " <tr>" & vbNewLine & _
     "  <td height=""25"" class=""baslik"">"
    for intSayac = 0 to intToplam
    if intSayac <> 0 then
     strStil = "none"
    else
     strStil = "block" 
    end if
     Response.Write "<div id=""tits" & intSayac & "-manset"" style=""DISPLAY: " & strStil & """>" & arrTumVeriler(intAlan02, intSayac) & "</div>" & vbNewLine
    next 
     Response.Write "  </td>" & vbNewLine & _
     " </tr>" & vbNewLine & _
     " <tr>" & vbNewLine & _
     "  <td>" & vbNewLine & _
     "   <table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""550"">" & vbNewLine & _
     "    <tr>" & vbNewLine & _
     "     <td valign=""top"" width=""300"">" & vbNewLine & _
     "      <table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""100%"">" & vbNewLine & _
     "       <tr>" & vbNewLine & _
     "        <td width=""300"" height=""250"">" & vbNewLine
    for intSayac = 0 to intToplam
    if intSayac <> 0 then
     strStil = "none"
    else
     strStil = "block" 
    end if
     Response.Write "         <div id=""tits" & intSayac & "-imaj"" style=""DISPLAY: " & strStil & """><img src=""resimler/" & arrTumVeriler(intAlan05, intSayac) & """ width=""300"" height=""250"" border=""1""></div>" & vbNewLine
    next  
    
    
     Response.Write "        </td>" & vbNewLine & _
     "       </tr>" & vbNewLine & _
     "       <tr>" & vbNewLine & _
     "        <td class=""yazi_01"">" & vbNewLine 
    for intSayac = 0 to intToplam
    if intSayac <> 0 then
     strStil = "none"
    else
     strStil = "block" 
    end if
     Response.Write "         <div id=""tits" & intSayac & "-spot"" style=""DISPLAY: " & strStil & """>" & arrTumVeriler(intAlan03, intSayac) & "</div>" & vbNewLine
    next  
     Response.Write "        </td>" & vbNewLine & _
     " </tr>" & vbNewLine & _
     
     "      </table>" & vbNewLine & _
     "     </td>" & vbNewLine
    %>
    <script type="text/javascript">
    <!--
    function displayDiv(divID)
    {
    <%
    for intSayac = 0 to intToplam
     Response.Write "hide('tits" & intSayac & "-manset');hide('tits" & intSayac & "-spot');hide('tits" & intSayac & "-imaj');" & vbNewLine
    next 
    %>
     document.getElementById('tits'+divID+'-manset').style.display = 'block';
     document.getElementById('tits'+divID+'-spot').style.display = 'block';
     document.getElementById('tits'+divID+'-imaj').style.display = 'block';
    }
    // -->
    </script>
    <%
     Response.Write "     <td valign=""top"" width=""250"">" & vbNewLine & _
     "      <table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""100%"">" & vbNewLine & _
     "       <tr>" & vbNewLine & _
     "        <td align=""center"" class=""yazi_02""><b>Haberler</b></td>" & vbNewLine & _
     "       </tr>" & vbNewLine
    for intSayac = 0 to intToplam
    if intSayac <> 0 then
     strStil = "none"
    else
     strStil = "block" 
    end if
     Response.Write "       <tr>" & vbNewLine & _
     "        <td height=""20"">&nbsp;<a href=""urun.asp?id=" & arrTumVeriler(intAlan01, intSayac) & """ onmouseover=displayDiv(" & intSayac & ") class=""Link_01"">" & arrTumVeriler(intAlan02, intSayac) & "</a></td>" & vbNewLine & _
     "       </tr>" & vbNewLine
    next  
     Response.Write "      </table>" & vbNewLine & _
     "     </td>" & vbNewLine & _		 
     "    </tr>" & vbNewLine & _
     "   </table>" & vbNewLine & _
     "	</td>" & vbNewLine & _
     " </tr>" & vbNewLine 
    else
     Response.Write " <tr>" & vbNewLine & _
     "  <td>Kayıt Yok!</td>" & vbNewLine & _
     " </tr>" & vbNewLine
    end if
     objConn.Close
    set objConn = Nothing
    %> 
    </table>
    
    </body>
    </html>
    
     
  10. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
     
  11. Narqotic

    Narqotic Bilgiliyim rank8

    Kayıt:
    22 Nisan 2007
    Mesajlar:
    1.365
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    Meslek:
    !!!
    Şehir:
    BeN SeNiN CaNıN İçİN ÖmRüMü BiR KiBRiTiN KaBıNDa T
    Konu : Anket
    Seviye : Basit
    Kaynak Dosyalar : http://rapidshare.com/files/6153939/anket.rar.html


    Anlaşılmasının kolay olması için çok basit mantık kullanılarak oluşturuldu.


    Oy verme sayfası
    [​IMG]

    Sonuç sayfası
    [​IMG]


    Kod:
    <%
    dim strConn
     strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("anket.mdb")
    
    set objConn = Server.CreateObject("ADODB.Connection")
     objConn.Open strConn 
    
    set objRs = Server.CreateObject("ADODB.Recordset")
     strSql = "SELECT TOP 1 * FROM tblAnket ORDER BY anket_tarihi DESC"
    objRs.open strSql, objConn, 3, 3
    
    
     intAnketID = objRs("anket_id")
     strAnketSorusu = objRs("anket_sorusu")
    
    If Request.QueryString("islem") = "true" then
    
     strSql = "UPDATE tblSecenek SET secenek_oy = secenek_oy + 1 WHERE secenek_id= " & Request.QueryString("id") & ";"
    
    If Int(Request.Cookies("anket")("id")) <> intAnketID then
     objConn.Execute strSql
     Response.Cookies("anket").Expires = Now() + 7
     Response.Cookies("anket")("id") = intAnketID
     Response.write "Teşekkürler"
    End if
    End if
    
     strSql = "SELECT * FROM tblSecenek WHERE anket_id = " & intAnketID
    set objRsSecenek = Server.CreateObject("ADODB.Recordset")
     objRsSecenek.Open strSql, objConn, 3, 3
     intToplam = 0
    
    While Not objRsSecenek.EOF
     intToplam = intToplam +  objRsSecenek("secenek_oy")
     objRsSecenek.MoveNext
    Wend
    
     objRsSecenek.MoveFirst
    
    If Request.QueryString("sonuc") = "true" OR Request.QueryString("islem") = "true" OR cInt(Request.Cookies("anket")("id")) = intAnketID then			
    If intToplam = 0 then 
     Response.write "sonuçlar"
    Else
    %>
    <table width="250">
     <tr>
      <td colspan="3"><%=strAnketSorusu%></td>
     </tr>
    <%
    while not objRsSecenek.EOF 
     intToplamOy = (objRsSecenek("secenek_oy") / intToplam) * 100
    %>
     <tr>
      <td><%=objRsSecenek("secenek")%></td>
      <td width='100'><img src='resimler/anket.gif' height='5' width='<%=Round(intToplamOy,0)%>'></td>
      <td><%=Round(intToplamOy,1)%> %</td>
     </tr>
    <%
     objRsSecenek.movenext
    wend 
    %>
    </table>
    <br>
    <%
     Response.write intToplam & " oy"
    End If
    Else   
    %>
    <table width="250">
    <form name="poll" action="anket.asp?sonuc=true" method="get">
    <input type="hidden" name="islem" value="true">
     <tr>
      <td colspan="3"><%=strAnketSorusu%></td>
     </tr>
    <%
    while not objRsSecenek.EOF 
    %>
     <tr>
      <td><%=objRsSecenek("secenek")%></td>
      <td><input type="radio" name="id" value="<%=objRsSecenek("secenek_id")%>"></td>
     </tr>
    <%
     objRsSecenek.movenext
    wend
    %>
     <tr>
      <td colspan="2"><input type="submit" value="Gönder"><br><a href="anket.asp?sonuc=true">Sonuçlar</a></td>
     </tr>
    </form>
    </table>
    <%
    End if
    %> 
     
  12. tanerik

    tanerik Keşfediyorum rank8

    Kayıt:
    16 Nisan 2007
    Mesajlar:
    10
    Beğenilen Mesajlar:
    0
    Ödül Puanları:
    0
    tebrik ettim wala . yok yok . Emegine saglik.